Manipulation des cellules et des plages en VBA
En VBA, la manipulation des cellules et des plages est fondamentale. Cette section couvre l'utilisation des objets
Cells() et
Range(), leurs propriétés essentielles (comme
Offset,
Value), ainsi que la variabilisation des classeurs (
Workbooks), feuilles (
Worksheets) et cellules. Ces concepts sont indispensables pour écrire du code VBA dynamique et robuste.
1. Différence entre Cells() et Range()
Cells()
. Utilisé pour référencer une seule cellule en utilisant ses coordonnées (ligne, colonne).
. Syntaxe : Cells(Ligne, Colonne)
-> Ligne : Numéro de la ligne.
-> Colonne : Numéro ou nom de la colonne.
Exemple
Cells(1, 1).Value = "A1" ' Écrit "A1" dans la cellule A1
Cells(2, "B").Value = "B2" ' Écrit "B2" dans la cellule B2
Range()
. Utilisé pour référencer une ou plusieurs cellules en utilisant leurs adresses.
. Syntaxe : Range("Adresse")
-> Adresse : Référence de la cellule ou plage (ex. :"A1", "A1:B10").
Exemple
Range("A1").Value = "A1" ' Écrit "A1" dans la cellule A1
Range("B1:B5").Value = "Plage" ' Écrit "Plage" dans toutes les cellules B1 à B5
2. Propriétés essentielles
Value
Permet de lire ou écrire la valeur d’une cellule ou d’une plage.
Exemple
Range("A1").Value = 100 ' Écrit 100 dans A1
MsgBox Cells(1, 1).Value ' Affiche la valeur de A1
Offset
. Permet de déplacer la référence d'une cellule ou d’une plage en ligne et/ou colonne.
. Syntaxe : Offset(NbLignes, NbColonnes)
-> NbLignes : Nombre de lignes à déplacer (positif ou négatif).
-> NbColonnes : Nombre de colonnes à déplacer (positif ou négatif).
Exemple
Range("A1").Offset(1, 0).Value = "A2" ' Écrit "A2" dans la cellule en dessous de A1
Cells(1, 1).Offset(0, 1).Value = "B1" ' Écrit "B1" dans la cellule à droite de A1
Address
Renvoie l’adresse d’une cellule ou d’une plage en texte.
Exemple
MsgBox Range("B3").Address ' Affiche "$B$3"
Interior.Color
Modifie la couleur de fond d'une cellule.
Exemple
Range("A1").Interior.Color = vbYellow ' Colore A1 en jaune
Font.Bold
Met le texte en gras.
Exemple
Range("A1").Font.Bold = True
3. Utilisation des objets Worksheets() et Workbooks()
Worksheets()
. Référence une feuille de calcul spécifique dans un classeur.
. Syntaxe : Worksheets("NomFeuille") ou Worksheets(Index)
Exemple
Worksheets("Feuil1").Range("A1").Value = "Feuil1" ' Écrit dans Feuil1
Worksheets(2).Range("A1").Value = "Deuxième feuille" ' Écrit dans la 2e feuille
Workbooks()
. Référence un classeur spécifique ouvert dans Excel.
. Syntaxe : Workbooks("NomFichier.xlsx")
Exemple
Workbooks("Classeur1.xlsx").Worksheets("Feuil1").Range("A1").Value = "Bonjour"
Variabiliser le classeur et la feuille
Pour rendre le code plus dynamique, vous pouvez stocker les objets Workbook et Worksheet dans des variables.
. Référence un classeur spécifique ouvert dans Excel.
Exemple
Dim MonClasseur As Workbook
Dim MaFeuille As Worksheet
Set MonClasseur = Workbooks("Classeur1.xlsx")
Set MaFeuille = MonClasseur.Worksheets("Feuil1")
MaFeuille.Range("A1").Value = "Dynamique"
4. Variabiliser la cellule
Les cellules et plages peuvent également être variabilisées pour plus de flexibilité.
Exemple
Dim MaCellule As Range
Set MaCellule = Worksheets("Feuil1").Range("B2")
MaCellule.Value = "Cellule Dynamique"
Pour travailler avec plusieurs cellules :
Dim Plage As Range
Set Plage = Worksheets("Feuil1").Range("A1:A5")
Plage.Font.Bold = True ' Met en gras toutes les cellules de la plage
5. Exemples pratiques
Exemple 1 : Écrire des valeurs dans une colonne avec Offset
Sub RemplirColonne()
Dim i As Integer
For i = 1 To 10
Range("A1").Offset(i - 1, 0).Value = i
Next i
End Sub
Résultat : Remplit la colonne A avec les valeurs de 1 à 10.
Exemple 2 : Copier des données d’une feuille à une autre
Sub CopierDonnées()
Dim Source As Worksheet, Destination As Worksheet
Set Source = Worksheets("Feuil1")
Set Destination = Worksheets("Feuil2")
Source.Range("A1:A10").Copy Destination.Range("B1")
End Sub
Résultat : Copie les données de A1:A10 de Feuil1 dans la colonne B de Feuil2.
Exemple 3 : Calculer la somme d’une plage et écrire le résultat
Sub SommePlage()
Dim Somme As Double
Dim Plage As Range
Set Plage = Worksheets("Feuil1").Range("A1:A5")
Somme = WorksheetFunction.Sum(Plage)
Worksheets("Feuil1").Range("A6").Value = "Somme : " & Somme
End Sub
Résultat : Calcule la somme des cellules A1:A5 et écrit le résultat dans A6.
6. Astuces pour manipuler les cellules et plages
Références dynamiques
Utilisez des variables pour définir les plages et cellules.
Exemple :
Dim DerniereLigne As Long
DerniereLigne = Worksheets("Feuil1").Cells(Rows.Count, 1).End(xlUp).Row
Évitez les sélections inutiles
Plutôt que :
Range("A1").Select
Selection.Value = "Texte"
Préférez :
Range("A1").Value = "Texte"
Boucles pour les plages
Utilisez For Each pour parcourir une plage.
Exemple :
Dim Cellule As Range
For Each Cellule In Range("A1:A5")
Cellule.Value = Cellule.Row
Next Cellule
7. Exercice : Manipuler cellules et plages
Objectif
. Remplissez la colonne B avec les carrés des valeurs de la colonne A (de A1 à A10).
. Colorez en jaune les cellules de la colonne B.
Solution
Sub CalculerCarres()
Dim i As Integer
For i = 1 To 10
Cells(i, 2).Value = Cells(i, 1).Value ^ 2
Cells(i, 2).Interior.Color = vbYellow
Next i
End Sub